Apache/mod_perl Handler (Practical mod

D.6. Apache/mod_perl Handler

There isn't much to change between the implementation of a Perl CGI script such as the example above and the equivalent Apache/mod_perl handler.

The great advantage of using mod_perl is that it allows you to keep a Template object persistent in memory. The main benefit of this is that Perl can parse and compile all the Template Toolkit code and all your application code once when the server starts, rather than repeating it for each request. The other important benefit is that the Template object will cache previously used templates in a compiled state, from which they can be redeployed extremely quickly. A call to process a template becomes as efficient as a call to a precompiled Perl subroutine (which is indeed how it is implemented under the hood), bringing you runtime machine efficiency as well as the development-time human efficiency and convenience of using a template-driven presentation system.

Example D-5 shows a typical mod_perl handler roughly equivalent to the earlier Perl script.

Example D-5. Apache/MyTemplate.pm

package Apache::MyTemplate;

use strict;
use Apache::Constants qw( :common );
use Template;
use vars qw( $TT );

sub handler {
  my $r = shift;

  # create or reuse existing Template object
  $TT ||= Template->new({
      INCLUDE_PATH  => '/usr/local/tt2/templates',
  });

  my $data = {
      uri => $r->uri,
      copyright => '&copy; 2002 Andy Wardley',
      weblinks  => [
           {
            url   => 'https://perl.apache.org/',
            title => 'Apache/mod_perl',
           },
           {
            url   => 'https://tt2.org/',
            title => 'Template Toolkit',
           },
      ],
      # ...and so on...
  };

  $r->content_type('text/html');
  $r->send_http_header;

  $TT->process('example.html', $data, $r) || do {
      $r->log_reason($TT->error( ));
      return SERVER_ERROR;
  };

  return OK;
}
1;

You need to adjust the value of INCLUDE_PATH to point to the directory where header, example.html, and footer were created.

Here's the configuration section for the httpd.conf file:

PerlModule Apache::MyTemplate
<Location /example2>
  SetHandler perl-script
  PerlHandler Apache::MyTemplate
</Location>

Of course, it's not particularly useful to have the template name hardcoded as it is here, but it illustrates the principle. You can implement whatever kind of strategy you like for mapping requests onto templates, using the filename, path information, or pretty much anything else that takes your fancy. No doubt you can already spot numerous other enhancements that you might make to your own handlers.

Figure D-1 shows what you should expect when issuing a request to /example2.

D.6. Apache/mod_perl Handler

Example D-5. Apache/MyTemplate.pm

Figure D-1. A sample response